TBarCode SDK是一款可以在任意應用程序和打印機下生成和打印所有條碼的條碼軟件組件。TBarCode SDK對于Microsoft® Office 用戶以及軟件開發者提供條碼打印。使用此款條碼軟件組件您可以以完美效果生成和打印所有用于工業和商業條碼符號。

【TBarCode SDK最新版下載】

一. 如何在Word VBA中以編程方式添加條形碼控件？

示例代碼：

    Dim barcodeShape As InlineShape

    ' switch to design mode (optional)
    ' ActiveDocument.ToggleFormsDesign
    
    ' Insert bar code object at actual position in document
    Set barcodeShape = Selection.InlineShapes.AddOLEControl(ClassType:="TBarCode10.TBarCode10.1")

    ' change size
    barcodeShape.Width = 200
    barcodeShape.Height = 100

    ' adjust bar code properties programmatically
    barcodeShape.OLEFormat.Object.Barcode = 20    ' 20 = Code-128
    barcodeShape.OLEFormat.Object.Text = "Hello"

“AddOLEControl”函數接受第二個參數，該參數可以是放置條形碼控件的Range對象。

二. 如何生成優化的PDF417位圖圖像？

請使用此代碼段作為起點：

Barcode.Barcode = eBC_PDF417
Barcode.Text = "My Data... "

' the following settings produce a barcode 82,296 mm wide
' if your barcode should have a constant width, set the data columns
' as shown below (increase/decrease to make wider/smaller symbol)

Barcode.PDF417.Columns = 15

Dim X, Y
Dim Scaling
Dim Dpi

' define ratio of module width (small bar width) to row height
X = 1
Y = 1       ' keeps default ratio, which is 1:3
'Y = 3 / 2  ' creates 1:5 ratio

Dpi = 300     ' 300 dpi printer
Scaling = 3   ' 1 Module (smallest bar) = 3 Pixels = 0.254mm

Dim Cols
Dim Rows

Cols = Barcode.Get2DXCols()
Rows = Barcode.Get2DXRows()

Dim XSize
Dim YSize

XSize = Int(X * Cols)     
YSize = Int(Y * Rows)   

' scale with DPI enlarging factor
XSize = XSize * Scaling
YSize = YSize * Scaling

' Save barcode as bitmap
Barcode.SaveImage "c:\temp\barcode.bmp", eIMBmp, XSize, YSize, Dpi, Dpi

三. 已將TBarCode添加到我的Word 2003文檔中，無法保護我的Word文檔？

必須離開設計模式才能保護文檔。如果插入條形碼控件，則文檔將切換到設計模式。通過Control Toolbox您可以離開設計模式，然后您就可以保護文檔。

四. 如何使用CopyToClipboard在Excel VBA中生成數據矩陣？

請使用此代碼段作為起點：

Private Declare Function CreateCompatibleDC Lib "gdi32" (ByVal hdc As Long)  As Long
Private Declare Function DeleteDC Lib "gdi32" (ByVal hdc As Long) As Long

Dim obj As New TBarCode10
Dim nWidth As Long
Dim nHeight As Long
Dim dc As Long

  With obj
    .BarCode = eBC_DataMatrix
    .DataMatrix.Size = eDMSz_32x32
    .Text = myData

    .QuietZoneUnit = eMUModules
    .QuietZoneBottom = 2
    .QuietZoneLeft = 2
    .QuietZoneTop = 2
    .QuietZoneRight = 2

    .ModuleWidth = "508"
    .SizeMode = eSizeMode_CustomModuleWidth
    .Dpi = 1440 / Screen.TwipsPerPixelX ' screen resolution in dpi

    dc = CreateCompatibleDC(0) ' screen DC

    nWidth = .BCWidthHdc(dc, 96, 96, eMUPixel) + 0.9999   ' module width should be set
    nHeight = .BCHeightHdc(dc, 96, 96, eMUPixel) + 0.9999 ' module width should be set
   
    .CopyToClipboardEx dc, nWidth, nHeight, ""

    DeleteDC(dc)
  End With

五. 通過VBA打印：條形碼未更新？

您可以更改鏈接單元格或條形碼控件的內容，然后直接從VBA中打印。但是你看到條形碼控件仍然包含舊值。原因是Excel在打印之前不會向ActiveX控件發送重繪命令（如果在VBA中完成）。這是Excel中的錯誤。

有一種強制重繪對象的解決方法，您需要在VBA中以編程方式處理每個條形碼ActiveX控件并在打印前更改其大小。然后由Excel重新繪制。

'redraw a single barcode object by adressing it through its instance name

Dim origValue
origValue = TBarCode101.Width
TBarCode101.Width = origValue + 1
TBarCode101.Width = origValue

' redraw all ActiveX Controls on the current sheet

Sub UpdateOLEControls()
Dim myShape As shape
Dim counter As Integer
Dim origWidth As Single
For counter = 1 To ActiveSheet.Shapes.Count
  Set myShape = ActiveSheet.Shapes(counter)
  If (myShape.Type = msoOLEControlObject) Then
    ' resize => force redraw
    origWidth = myShape.Width
    myShape.Width = origWidth + 1
    myShape.Width = origWidth
  End If
Next counter
End Sub

六. 如何在GS1條形碼中編碼FNC1？

要將功能字符FNC1添加到條形碼數據，請按以下步驟操作：

1. 輸入條形碼數據“10222333 \ F 15100701”。
2. 切換到“Settings”選項卡并檢查Escape Sequences。
3. 將插入FNC1并在HRT中自動識別應用程序標識符（AI = 15）。
4. 在Barcode Studio 11.5+中，您可以使用新的GS1應用程序標識助手。