MailBee Objects是一個(gè)組件集合。您可以使用該控件創(chuàng)建并將郵件發(fā)送到SMTP服務(wù)器并從POP3服務(wù)器接收、解析以及刪除電子郵件，還能在IMAP4服務(wù)器上管理電子郵件以及文件夾。它同樣支持SSL以及S/MIME以獲得更好的安全性能。MailBee控件能在ASP、VB、C++或任何支持ActiveX技術(shù)的語言中使用。

點(diǎn)擊下載最新版MailBee Objects

本示例使用單個(gè)模板和數(shù)據(jù)庫發(fā)送多封電子郵件。

對(duì)于每個(gè)消息，從數(shù)據(jù)庫中獲取的實(shí)際值將替換模板中的占位符。因此，所有電子郵件將具有相同的外觀，但仍將是個(gè)性化的。本示例代碼使用ADO的Connection對(duì)象連接到MS Access數(shù)據(jù)庫。然后，ADO的Recordset對(duì)象被“電子郵件”表中的值填充。該表的每個(gè)記錄然后用于生成單個(gè)電子郵件。

該代碼假定數(shù)據(jù)庫位于C：\ Docs \ simple_merge.mdb文件中，并且“電子郵件”表如下所示：

• 注意1：該示例通過單個(gè)SMTP連接發(fā)送所有電子郵件（這提供了最佳性能）。但是，某些SMTP服務(wù)器只允許通過同一連接發(fā)送少量電子郵件。
• 注意2：為減少批量發(fā)送應(yīng)用程序的響應(yīng)時(shí)間，您可以告訴MailBee在后臺(tái)發(fā)送電子郵件。

Visual Basic：

' Mailer object
Dim objSMTP

' ADO Connection object
Dim objConn

' ADO Recordset object
Dim rsEmails

' Merge patterns (Body and "To:", all other fields remain
' unchanged for all e-mails in the mailing list)
Dim strBodyPattern, strToPattern

' Define body pattern
strBodyPattern = "Hello %%FIRST_NAME%%, " & vbCrLf & _
  "You are welcome to visit our site at:" & vbCrLf & _
  "http://www.site.com" & vbCrLf & vbCrLf & _
  "Sincerely, Site Team"

' Define "To:" pattern (will look like
' "John Doe " in e-mail)
strToPattern = "%%FIRST_NAME%% %%LAST_NAME%% <%%EMAIL%%>"

' Create SMTP mailer component
Set objSMTP  = CreateObject("MailBee.SMTP")

' Enable logging SMTP session into a file. If any
' errors occur, the log can be used to investigate
' the problem.
objSMTP.EnableLogging = True
objSMTP.LogFilePath = "C:\smtp_log.txt"
objSMTP.ClearLog

' Unlock mailer component
objSMTP.LicenseKey = "put your license key here"

' Specify SMTP server name
objSMTP.ServerName = "smtp.site.com"

' Comment next 3 lines if your SMTP server does not
' require SMTP authentication
objSMTP.AuthMethod = 2
objSMTP.UserName = "your mail account name"
objSMTP.Password = "your mail account password"

' Connect to the server. We use single connection
' for sending all e-mails in the database.
If objSMTP.Connect Then
  ' Plain-text e-mail. Change to 1 to send HTML e-mail
  objSMTP.BodyFormat = 0
  
  ' Specify "From:" and "Subject:". They remain unchanged
  ' for all the e-mails.
  objSMTP.Message.FromAddr = "Site Team "
  objSMTP.Message.Subject = "Invitation"

  ' Create ADO Connection object
  Set objConn  = CreateObject("ADODB.Connection")

  ' Connect to Access database
  objConn.Open "Provider=Microsoft.Jet.OLEDB.4.0; " & _
    "Data Source=C:\Docs\simple_merge.mdb;"

  ' Create ADO Recordset object
  Set rsEmails = CreateObject("ADODB.Recordset")
  
  ' Open "emails" table. This table is
  ' actual data source for the merge
  rsEmails.Open "emails", objConn
  
  ' Loop through the table
  While Not rsEmails.EOF

    ' Merge body pattern and actual data
    ' from the database
    objSMTP.Message.BodyText = strBodyPattern
    objSMTP.Message.BodyText = Replace(objSMTP.Message.BodyText, "%%FIRST_NAME%%", rsEmails("first_name"))

    ' Merge "To:" pattern and actual data
    ' from the database
    objSMTP.Message.ToAddr = strToPattern
    objSMTP.Message.ToAddr = Replace(objSMTP.Message.ToAddr, "%%FIRST_NAME%%", rsEmails("first_name"))
    objSMTP.Message.ToAddr = Replace(objSMTP.Message.ToAddr, "%%LAST_NAME%%", rsEmails("last_name"))
    objSMTP.Message.ToAddr = Replace(objSMTP.Message.ToAddr, "%%EMAIL%%", rsEmails("email"))

    ' Try to send e-mail
    If Not objSMTP.Send Then
      ' Notify user on sending error
      MsgBox "Error #" & objSMTP.ErrCode & ", " & objSMTP.ErrDesc
    End If
    
    ' Proceed with the next record in the table
    rsEmails.MoveNext
  Wend
  
  ' Close the table and the whole database
  rsEmails.Close
  objConn.Close

  ' Free database-related objects
  Set rsEmails = Nothing
  Set objConn = Nothing

  ' Disconnect from SMTP server
  objSMTP.Disconnect
Else
  ' Notify user on connection error
  MsgBox "Error #" & objSMTP.ErrCode & ", " & objSMTP.ErrDesc
End If

<% ' Mailer object Dim objSMTP ' ADO Connection object Dim objConn ' ADO Recordset object Dim rsEmails ' Merge patterns (Body and "To:", all other fields remain ' unchanged for all e-mails in the mailing list) Dim strBodyPattern, strToPattern ' Define body pattern strBodyPattern = "Hello %%FIRST_NAME%%, " & vbCrLf & _ "You are welcome to visit our site at:" & vbCrLf & _ "http://www.site.com" & vbCrLf & vbCrLf & _ "Sincerely, Site Team" ' Define "To:" pattern (will look like ' "John Doe " in e-mail)
strToPattern = "%%FIRST_NAME%% %%LAST_NAME%% <%%EMAIL%%>"

' Create SMTP mailer component
Set objSMTP  = Server.CreateObject("MailBee.SMTP")

' Enable logging SMTP session into a file. If any
' errors occur, the log can be used to investigate
' the problem.
objSMTP.EnableLogging = True
objSMTP.LogFilePath = "C:\smtp_log.txt"
objSMTP.ClearLog

' Unlock mailer component
objSMTP.LicenseKey = "put your license key here"

' Specify SMTP server name
objSMTP.ServerName = "smtp.site.com"

' Comment next 3 lines if your SMTP server does not
' require SMTP authentication
objSMTP.AuthMethod = 2
objSMTP.UserName = "your mail account name"
objSMTP.Password = "your mail account password"

' Connect to the server. We use single connection
' for sending all e-mails in the database.
If objSMTP.Connect Then
  ' Plain-text e-mail. Change to 1 to send HTML e-mail
  objSMTP.BodyFormat = 0
  
  ' Specify "From:" and "Subject:". They remain unchanged
  ' for all the e-mails.
  objSMTP.Message.FromAddr = "Site Team "
  objSMTP.Message.Subject = "Invitation"

  ' Create ADO Connection object
  Set objConn  = Server.CreateObject("ADODB.Connection")

  ' Connect to Access database
  objConn.Open "Provider=Microsoft.Jet.OLEDB.4.0; " & _
    "Data Source=C:\Docs\simple_merge.mdb;"

  ' Create ADO Recordset object
  Set rsEmails = Server.CreateObject("ADODB.Recordset")
  
  ' Open "emails" table. This table is
  ' actual data source for the merge
  rsEmails.Open "emails", objConn
  
  ' Loop through the table
  While Not rsEmails.EOF

    ' Merge body pattern and actual data
    ' from the database
    objSMTP.Message.BodyText = strBodyPattern
    objSMTP.Message.BodyText = Replace(objSMTP.Message.BodyText, "%%FIRST_NAME%%", rsEmails("first_name"))

    ' Merge "To:" pattern and actual data
    ' from the database
    objSMTP.Message.ToAddr = strToPattern
    objSMTP.Message.ToAddr = Replace(objSMTP.Message.ToAddr, "%%FIRST_NAME%%", rsEmails("first_name"))
    objSMTP.Message.ToAddr = Replace(objSMTP.Message.ToAddr, "%%LAST_NAME%%", rsEmails("last_name"))
    objSMTP.Message.ToAddr = Replace(objSMTP.Message.ToAddr, "%%EMAIL%%", rsEmails("email"))

    ' Try to send e-mail
    If Not objSMTP.Send Then
      ' Notify user on sending error
      Response.Write "Error #" & objSMTP.ErrCode & ", " & objSMTP.ErrDesc & "
"
    End If
    
    ' Proceed with the next record in the table
    rsEmails.MoveNext
  Wend
  
  ' Close the table and the whole database
  rsEmails.Close
  objConn.Close

  ' Free database-related objects
  Set rsEmails = Nothing
  Set objConn = Nothing

  ' Disconnect from SMTP server
  objSMTP.Disconnect
Else
  ' Notify user on connection error
  Response.Write "Error #" & objSMTP.ErrCode & ", " & objSMTP.ErrDesc & "
"
End If
%>

==========================================

如果想要購買正版授權(quán)MailBee.NET Objects的朋友，可以聯(lián)系

關(guān)注慧聚IT微信公眾號(hào) ???，了解產(chǎn)品的最新動(dòng)態(tài)及最新資訊。